Import von Bildern über Links in CSV

[Handwerkshop24]

Hallo 

bekommen vom Hersteller eine csv mit Artikeldaten und Links zu Bildern. 

Wie bekommen ich diese in die Warenwirtschaft und dann in den Shop . Shopsytem ist Shopware 6

[Ralf Marx]

Hallo Handwerkshop24,

die Bilder werden Sie brauchen um diese hochladen zu können. Mit einem Link funktioniert das meines Wissens nach nicht.

[SK_Musketier]

Hallo,

nein das geht in der Vario leider nicht.

Je nach Größenordnung ist das vielleicht eine Option. Ich habs getestet mit ca. 6.000 links/bildern die jeweils zwischen 100-300kb groß waren. Das ging problemlos.

Ich hab mir als Workaround ein Excel Makro gebaut mit dem Ich Bilder aus dem Internet ziehen kann wenn ich eine Liste mit URL's habe.

Dann könntest du die Liste mit den Links in eine Excelliste laden und ein Neues Makro erstellen. Bei mir sieht das Makro dann so aus:

Sub DownloadImages()
    Dim ws As Worksheet
    Dim cell As Range
    Dim objHTTP As Object
    Dim objStream As Object
    Dim downloadPath As String
    
    ' Set the target download folder path
    downloadPath = "Hier Den Ordner auf deinem PC eintragen wo die Bilder gespeichert werden sollen" ' Ändere dies zu deinem gewünschten Zielordner
    
    ' Set the worksheet containing the URLs
    Set ws = ThisWorkbook.Sheets("Tabelle3") ' Ändere dies zu deinem Arbeitsblatt-Name
    
    ' Loop through each cell in the specified range
    For Each cell In ws.Range("A1:A" & ws.Cells(ws.Rows.Count, "A").End(xlUp).Row) ' Ändere dies zur Spalte in der deine Links stehen
        If cell.Value <> "" Then
            On Error GoTo ErrorHandler
            ' Create the HTTP and Stream objects
            Set objHTTP = CreateObject("MSXML2.XMLHTTP")
            Set objStream = CreateObject("ADODB.Stream")
            
            ' Send a GET request to the URL
            objHTTP.Open "GET", cell.Value, False
            objHTTP.send
            
            ' Save the response to a file
            objStream.Open
            objStream.Type = 1 ' 1 = binary
            objStream.Write objHTTP.responseBody
            objStream.SaveToFile downloadPath & Mid(cell.Value, InStrRev(cell.Value, "/") + 1), 2 ' 2 = overwrite
            objStream.Close
            
            ' Clean up the objects
            Set objHTTP = Nothing
            Set objStream = Nothing
        End If
    Next cell
    Exit Sub
    
ErrorHandler:
    MsgBox "Fehler bei der URL: " & cell.Value & vbCrLf & Err.Description
    Resume Next
End Sub

 

Wenn du die Bilder Lokal hast, kannst du sie wie sonst auch in die Vario importieren wenn du Artikel anlegst.

 

Bearbeitet 7. Januar von SK_Musketier
Infos zur Menge hinzugefügt